汎用オブジェクト存在チェック(97 以前）

対象バージョン : 97 (,2000, 2002, 2003, 2007)
最終更新日 : 2007/02/12 ( オリジナル作成日：1996/11/16 )

概　要

　プロシージャ内で、指定されたオブジェクト が存在するか否かをチェックするユーザー定義関数です。

構　文

　 IsObjExist(objectType, ObjectName)

解　説

IsObjExist 関数の戻り値はブール型 (Boolean)です。

引数に指定されてオブジェクトが存在する場合は True を、存在しない場合 は False を返します。

IsObjExist 関数では次の引数を使用します。

ObjectType に誤った値を設定した場合や、ObjectName が Null の場合、 IsObjExist 関数は False を返します。

ユーザー定義関数

Function IsObjExist(Arg_ObjType As Integer, Arg_ObjName) As Boolean
Dim db As DAO.DATABASE
Dim tbd As DAO.TableDef
Dim qd As DAO.QueryDef
Dim ContName As String
Dim doc As DAO.Document

IsObjExist = False
If IsNull(Arg_ObjName) Or Arg_ObjName = "" Then Exit Function

Set db = CurrentDb
Select Case Arg_ObjType
Case acTable
    db.TableDefs.Refresh
    For Each tbd In db.TableDefs
        If tbd.Name = Arg_ObjName Then
            IsObjExist = True
            Exit For
        End If
    Next
Case acQuery
    db.QueryDefs.Refresh
    For Each qd In db.QueryDefs
        If qd.Name = Arg_ObjName Then
            IsObjExist = True
            Exit For
        End If
    Next
Case acForm, acReport, acMacro, acModule
    Select Case Arg_ObjType
    Case acForm
        ContName = "Forms"
    Case acReport
        ContName = "Reports"
    Case acMacro
        ContName = "Scripts"
    Case acModule
        ContName = "Modules"
    End Select
    db.Containers(ContName).Documents.Refresh
    For Each doc In db.Containers(ContName).Documents
        If doc.Name = Arg_ObjName Then
            IsObjExist = True
            Exit For
        End If
    Next
End Select
End Function

補　足

• 2000 以降で新たに追加されたデータアクセスページ等のオブジェクトを使用しない場合は、このプロシージャでも動作します。
• DAO への参照設定が必要です。

改定履歴

• 1999/09/01 2000 についての補足追加。
• 2003/11/02 DAO オブジェクト変数の宣言で "DAO" 修飾を追加。

目次へ戻る