プロシージャによるインポート・エクスポート定義の作成

対象バージョン :  97, 2000(MDB), 2002(MDB), 2003(MDB)
最終更新日 : 2005/04/25 （オリジナル作成日：1998/10/16）

概　要　

インポート・エクスポートの定義は、MSysIMEXSpecs と MSysIMEXColumns の二つのシステムテーブルに保存されています。

プロシージャによって新たな定義を作成するサンプルです。

解　説

以下のサンプルプロシージャは、"区切り記号付き" ファイル用で、フィールドは 「フィールド1」 一つを持つ定義を、定義名「定義1」として作成するものです。

Public Sub CreateIMEX()
Dim db As DAO.Database
Dim rsS As DAO.Recordset
Dim rsC As DAO.Recordset
Dim lngID As Long
On Error GoTo CreateIMEX_err

Set db = CurrentDb
Set rsS = db.OpenRecordset("MSysIMEXSpecs", dbOpenDynaset, dbDenyWrite)
Set rsC = db.OpenRecordset("MSysIMEXColumns", dbOpenDynaset, dbDenyWrite)

With rsS
.AddNew
!DateDelim = "/"
!DateFourDigitYear = False
!DateLeadingZeros = False
!DateOrder = 5
!DecimalPoint = "."
!FieldSeparator = ","
' 97 で "Windows (ANSI)" の場合
!FileType = 0 
' 2000 以降で "日本語(シフト JIS)" の場合
' !FileType = 932
!SpecName = "定義1"
!SpecType = 1
!StartRow = 0
!TextDelim = """"
!TimeDelim = ":"
lngID = !SpecID ' オートナンバーでふられた値を保存
.Update
End With

With rsC
.AddNew
!Attributes = 0
!DataType = dbText
!FieldName = "フィールド1"
!IndexType = 0
!SkipColumn = False
!SpecID = lngID
!Start = 1
!Width = 20
.Update
End With

Exit Sub
CreateIMEX_err:
MsgBox "Error Occured. Code=" & Err.Number & ", Description=" & Err.Description
Exit Sub
End Sub

補　足

• MSysIMEXSpecs, MSysIMEXColumns は、新規作成後の mdb には存在しません。初回のインポートまたはエクスポートのウィザードで定義を保存した際に作成されます。
• 各フィールドへの設定値については「インポート・エクスポート定義ファイルの内容」をご参照ください。

改定履歴

• 1999/08/29 Access 2000 の記述追加
• 2003/11/11 DAO オブジェクト変数の宣言に "DAO" 修飾を追加。

目次へ戻る